Contract Source Code (Solidity Standard Json-Input format)

IDE

• Blockscan IDE

More Options

• Similar
• Compare

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {ERC165Facet} from "../../../ERC165/ERC165Facet.sol";
import {ERC165Lib} from "../../../ERC165/ERC165Lib.sol";

import {IAccessControl} from "../../../access/IAccessControl.sol";
import {IAccessControlRecursive} from "../../../access/IAccessControlRecursive.sol";
import {AccessControlRecursiveFacet} from "../../../access/AccessControlRecursiveFacet.sol";

import {IContractURI} from "../../../ContractURI/IContractURI.sol";
import {ContractURILib} from "../../../ContractURI/ContractURILib.sol";
import {ContractURIFacet} from "../../../ContractURI/ContractURIFacet.sol";

import {IERC721} from "../IERC721.sol";
import {ERC721Facet} from "../ERC721Facet.sol";
import {ERC721Lib} from "../ERC721Lib.sol";

import {IERC721MintableAutoId} from "../IERC721MintableAutoId.sol";
import {ERC721MintableAutoIdFacet} from "../ERC721MintableAutoIdFacet.sol";

import {IERC721Metadata} from "../IERC721Metadata.sol";
import {IERC721BaseURI} from "../IERC721BaseURI.sol";
import {ERC721BaseURILib} from "../ERC721BaseURILib.sol";
import {ERC721BaseURIFacet} from "../ERC721BaseURIFacet.sol";

import {IERC2981} from "../../../ERC2981/IERC2981.sol";
import {ERC2981Lib} from "../../../ERC2981/ERC2981Lib.sol";
import {ERC2981Facet} from "../../../ERC2981/ERC2981Facet.sol";

contract ERC721MintableAutoIdBaseURIFacet is
    ERC165Facet,
    AccessControlRecursiveFacet,
    ContractURIFacet,
    ERC721Facet,
    ERC721MintableAutoIdFacet,
    ERC721BaseURIFacet,
    ERC2981Facet
{}

contract ERC721MintableAutoIdBaseURIFacetInit {
    function initialize(
        string memory contractUri,
        string memory name,
        string memory symbol,
        string memory baseUri,
        address royaltyReceiver,
        uint96 feeNumerator
    ) external {
        ERC165Lib._init();
        ERC165Lib.__unsafe_registerInterface(type(IAccessControl).interfaceId, true);
        ERC165Lib.__unsafe_registerInterface(type(IAccessControlRecursive).interfaceId, true);
        ERC165Lib.__unsafe_registerInterface(type(IContractURI).interfaceId, true);
        ERC165Lib.__unsafe_registerInterface(type(IERC721).interfaceId, true);
        ERC165Lib.__unsafe_registerInterface(type(IERC721MintableAutoId).interfaceId, true);
        ERC165Lib.__unsafe_registerInterface(type(IERC721Metadata).interfaceId, true);
        ERC165Lib.__unsafe_registerInterface(type(IERC721BaseURI).interfaceId, true);
        ERC165Lib.__unsafe_registerInterface(type(IERC2981).interfaceId, true);

        ContractURILib._init(contractUri);
        ERC721Lib._init(name, symbol);
        ERC721BaseURILib._init(baseUri);
        ERC2981Lib._init(royaltyReceiver, feeNumerator);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.20;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be
     * reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Strings.sol)

pragma solidity ^0.8.20;

import {Math} from "./math/Math.sol";
import {SignedMath} from "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant HEX_DIGITS = "0123456789abcdef";
    uint8 private constant ADDRESS_LENGTH = 20;

    /**
     * @dev The `value` string doesn't fit in the specified `length`.
     */
    error StringsInsufficientHexLength(uint256 value, uint256 length);

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), HEX_DIGITS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toStringSigned(int256 value) internal pure returns (string memory) {
        return string.concat(value < 0 ? "-" : "", toString(SignedMath.abs(value)));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        uint256 localValue = value;
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = HEX_DIGITS[localValue & 0xf];
            localValue >>= 4;
        }
        if (localValue != 0) {
            revert StringsInsufficientHexLength(value, length);
        }
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal
     * representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return bytes(a).length == bytes(b).length && keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/math/Math.sol)

pragma solidity ^0.8.20;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    /**
     * @dev Muldiv operation overflow.
     */
    error MathOverflowedMulDiv();

    enum Rounding {
        Floor, // Toward negative infinity
        Ceil, // Toward positive infinity
        Trunc, // Toward zero
        Expand // Away from zero
    }

    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds towards infinity instead
     * of rounding towards zero.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        if (b == 0) {
            // Guarantee the same behavior as in a regular Solidity division.
            return a / b;
        }

        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or
     * denominator == 0.
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv) with further edits by
     * Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0 = x * y; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            if (denominator <= prod1) {
                revert MathOverflowedMulDiv();
            }

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator.
            // Always >= 1. See https://cs.stackexchange.com/q/138556/92363.

            uint256 twos = denominator & (0 - denominator);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also
            // works in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (unsignedRoundsUp(rounding) && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded
     * towards zero.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (unsignedRoundsUp(rounding) && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (unsignedRoundsUp(rounding) && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (unsignedRoundsUp(rounding) && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (unsignedRoundsUp(rounding) && 1 << (result << 3) < value ? 1 : 0);
        }
    }

    /**
     * @dev Returns whether a provided rounding mode is considered rounding up for unsigned integers.
     */
    function unsignedRoundsUp(Rounding rounding) internal pure returns (bool) {
        return uint8(rounding) % 2 == 1;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.20;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IContractURI} from "./IContractURI.sol";
import {ContractURILib} from "./ContractURILib.sol";
import {AccessControlRecursiveLib} from "../access/AccessControlRecursiveLib.sol";

contract ContractURIFacet is IContractURI {
    /**
     * @dev Returns collection-wide URI-accessible metadata
     */
    function contractURI() external view returns (string memory) {
        return ContractURILib._contractURI();
    }

    /**
     * @dev Set contract uri
     */
    function setContractURI(string memory uri) external {
        ContractURILib._setContractURI(uri);
    }
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IContractURI} from "./IContractURI.sol";
import {AccessControlRecursiveLib} from "../access/AccessControlRecursiveLib.sol";

/**
 * @dev Implements contract uri getter/setter
 */
library ContractURILib {
    bytes32 internal constant CONTRACT_URI_ROLE = bytes32(IContractURI.setContractURI.selector);

    bytes32 constant CONTRACT_URI_STORAGE =
        keccak256(abi.encode(uint256(keccak256("owlprotocol.storage.ContractURI")) - 1)) & ~bytes32(uint256(0xff));

    /// @custom:storage-location erc7201:owlprotocol.storage.ContractURI
    struct ContractURIStorage {
        string value;
    }

    function getData() internal pure returns (ContractURIStorage storage ds) {
        bytes32 position = CONTRACT_URI_STORAGE;
        assembly {
            ds.slot := position
        }
    }

    function _init(string memory uri) internal {
        __unsafe_setContractURI(uri);
    }

    /**
     * @dev Returns collection-wide URI-accessible metadata
     */
    function _contractURI() internal view returns (string memory) {
        return getData().value;
    }

    function _setContractURI(string memory uri) internal {
        AccessControlRecursiveLib._checkRoleRecursive(CONTRACT_URI_ROLE, msg.sender);
        __unsafe_setContractURI(uri);
    }

    function __unsafe_setContractURI(string memory uri) internal {
        getData().value = uri;
    }
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

/**
 * @dev IContractURI defines a contract with metadata. A 1:1 relationship between contract address and metdata uri.
 */
interface IContractURI {
    function contractURI() external view returns (string memory);
    function setContractURI(string memory uri) external;
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IERC165Register} from "./IERC165Register.sol";
import {ERC165Lib} from "./ERC165Lib.sol";
import {AccessControlRecursiveLib} from "../access/AccessControlRecursiveLib.sol";

contract ERC165Facet is IERC165Register {
    function supportsInterface(bytes4 interfaceId) external view returns (bool) {
        return ERC165Lib._supportsInterface(interfaceId);
    }

    function registerInterface(bytes4 interfaceId, bool supported) external {
        ERC165Lib._registerInterface(interfaceId, supported);
    }
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {AccessControlRecursiveLib} from "../access/AccessControlRecursiveLib.sol";
import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
import {IERC165Register} from "./IERC165Register.sol";

library ERC165Lib {
    bytes32 internal constant ERC165_ROLE = bytes32(IERC165Register.registerInterface.selector);

    bytes32 constant ERC165_STORAGE =
        keccak256(abi.encode(uint256(keccak256("erc165.storage")) - 1)) & ~bytes32(uint256(0xff));

    /// @custom:storage-location erc7201:erc165.storage
    struct ERC165Storage {
        mapping(bytes32 interfaceId => bool) _supportedInterfaces;
    }

    function getData() internal pure returns (ERC165Storage storage ds) {
        bytes32 position = ERC165_STORAGE;
        assembly {
            ds.slot := position
        }
    }

    function _init() internal {
        __unsafe_registerInterface(type(IERC165).interfaceId, true);
    }

    function _registerInterface(bytes4 interfaceId, bool supported) internal {
        AccessControlRecursiveLib._checkRoleRecursive(ERC165Lib.ERC165_ROLE, msg.sender);
        __unsafe_registerInterface(interfaceId, supported);
    }

    function __unsafe_registerInterface(bytes4 interfaceId, bool supported) internal {
        getData()._supportedInterfaces[interfaceId] = supported;
    }

    function _supportsInterface(bytes4 interfaceId) internal view returns (bool) {
        return getData()._supportedInterfaces[interfaceId];
    }
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";

/**
 * @dev IERC165 contract that stores its interface id support data. This is usually not
 * recommended due to gas overhead but is required when using an upgradeable Diamond contract.
 */
interface IERC165Register is IERC165 {
    function registerInterface(bytes4 interfaceId, bool supported) external;
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {AccessControlRecursiveLib} from "../access/AccessControlRecursiveLib.sol";

import {IERC2981} from "./IERC2981.sol";
import {IERC2981Facet} from "./IERC2981Facet.sol";
import {ERC2981Lib} from "./ERC2981Lib.sol";

contract ERC2981Facet is IERC2981Facet {
    /**
     * @inheritdoc IERC2981
     */
    function royaltyInfo(
        uint256 tokenId,
        uint256 salePrice
    ) external view returns (address receiver, uint256 royaltyAmount) {
        return ERC2981Lib._royaltyInfo(tokenId, salePrice);
    }

    /**
     * @inheritdoc IERC2981Facet
     */
    function setDefaultRoyalty(address receiver, uint96 feeNumerator) external {
        return ERC2981Lib._setDefaultRoyalty(receiver, feeNumerator);
    }

    /**
     * @inheritdoc IERC2981Facet
     */
    function deleteDefaultRoyalty() external {
        return ERC2981Lib._deleteDefaultRoyalty();
    }

    /**
     * @inheritdoc IERC2981Facet
     */
    function setTokenRoyalty(uint256 tokenId, address receiver, uint96 feeNumerator) external {
        return ERC2981Lib._setTokenRoyalty(tokenId, receiver, feeNumerator);
    }

    /**
     * @inheritdoc IERC2981Facet
     */
    function resetTokenRoyalty(uint256 tokenId) external {
        return ERC2981Lib._resetTokenRoyalty(tokenId);
    }
}

// SPDX-License-Identifier: MIT
// Originally from
// OpenZeppelin Contracts (last updated v5.0.0) (token/common/ERC2981.sol)
// Updated as library

pragma solidity ^0.8.20;

import {AccessControlRecursiveLib} from "../access/AccessControlRecursiveLib.sol";
import {IERC2981Facet} from "./IERC2981Facet.sol";

/**
 * @dev Implementation of the NFT Royalty Standard, a standardized way to retrieve royalty payment information.
 *
 * Royalty information can be specified globally for all token ids via {_setDefaultRoyalty}, and/or individually for
 * specific token ids via {_setTokenRoyalty}. The latter takes precedence over the first.
 *
 * Royalty is specified as a fraction of sale price. {_feeDenominator} is overridable but defaults to 10000, meaning the
 * fee is specified in basis points by default.
 *
 * IMPORTANT: ERC-2981 only specifies a way to signal royalty information and does not enforce its payment. See
 * https://eips.ethereum.org/EIPS/eip-2981#optional-royalty-payments[Rationale] in the ERC. Marketplaces are expected to
 * voluntarily pay royalties together with sales, but note that this standard is not yet widely supported.
 */
library ERC2981Lib {
    /**
     * @dev The default royalty set is invalid (eg. (numerator / denominator) >= 1).
     */
    error ERC2981InvalidDefaultRoyalty(uint256 numerator, uint256 denominator);

    /**
     * @dev The default royalty receiver is invalid.
     */
    error ERC2981InvalidDefaultRoyaltyReceiver(address receiver);

    /**
     * @dev The royalty set for an specific `tokenId` is invalid (eg. (numerator / denominator) >= 1).
     */
    error ERC2981InvalidTokenRoyalty(uint256 tokenId, uint256 numerator, uint256 denominator);

    /**
     * @dev The royalty receiver for `tokenId` is invalid.
     */
    error ERC2981InvalidTokenRoyaltyReceiver(uint256 tokenId, address receiver);

    bytes32 internal constant ERC2981_ROLE = bytes32(IERC2981Facet.setTokenRoyalty.selector);

    bytes32 constant ERC2981_STORAGE =
        keccak256(abi.encode(uint256(keccak256("erc2981.storage")) - 1)) & ~bytes32(uint256(0xff));

    struct RoyaltyInfo {
        address receiver;
        uint96 royaltyFraction;
    }

    /// @custom:storage-location erc7201:erc2981.storage
    struct ERC2981Storage {
        RoyaltyInfo _defaultRoyaltyInfo;
        mapping(uint256 tokenId => RoyaltyInfo) _tokenRoyaltyInfo;
    }

    function getData() internal pure returns (ERC2981Storage storage ds) {
        bytes32 position = ERC2981_STORAGE;
        assembly {
            ds.slot := position
        }
    }

    function _init(address receiver, uint96 feeNumerator) internal {
        __unsafe_setDefaultRoyalty(receiver, feeNumerator);
    }

    function _royaltyInfo(uint256 tokenId, uint256 salePrice) internal view returns (address, uint256) {
        RoyaltyInfo memory royalty = getData()._tokenRoyaltyInfo[tokenId];

        if (royalty.receiver == address(0)) {
            royalty = getData()._defaultRoyaltyInfo;
        }

        uint256 royaltyAmount = (salePrice * royalty.royaltyFraction) / _feeDenominator();

        return (royalty.receiver, royaltyAmount);
    }

    /**
     * @dev The denominator with which to interpret the fee set in {_setTokenRoyalty} and {_setDefaultRoyalty} as a
     * fraction of the sale price. Defaults to 10000 so fees are expressed in basis points, but may be customized by an
     * override.
     */
    function _feeDenominator() internal pure returns (uint96) {
        return 10000;
    }

    /**
     * @dev Sets the royalty information that all ids in this contract will default to.
     *
     * Requirements:
     *
     * - `receiver` cannot be the zero address.
     * - `feeNumerator` cannot be greater than the fee denominator.
     * - `msg.sender` has role ERC2981Role
     */
    function _setDefaultRoyalty(address receiver, uint96 feeNumerator) internal {
        AccessControlRecursiveLib._checkRoleRecursive(ERC2981_ROLE, msg.sender);
        __unsafe_setDefaultRoyalty(receiver, feeNumerator);
    }

    /**
     * @dev Sets the royalty information that all ids in this contract will default to.
     *
     * Requirements:
     *
     * - `receiver` cannot be the zero address.
     * - `feeNumerator` cannot be greater than the fee denominator.
     */
    function __unsafe_setDefaultRoyalty(address receiver, uint96 feeNumerator) internal {
        uint256 denominator = _feeDenominator();
        if (feeNumerator > denominator) {
            // Royalty fee will exceed the sale price
            revert ERC2981InvalidDefaultRoyalty(feeNumerator, denominator);
        }
        if (receiver == address(0)) {
            revert ERC2981InvalidDefaultRoyaltyReceiver(address(0));
        }

        getData()._defaultRoyaltyInfo = RoyaltyInfo(receiver, feeNumerator);
    }

    /**
     * @dev Removes default royalty information.
     */
    function _deleteDefaultRoyalty() internal {
        AccessControlRecursiveLib._checkRoleRecursive(ERC2981_ROLE, msg.sender);
        __unsafe_deleteDefaultRoyalty();
    }

    /**
     * @dev Removes default royalty information.
     */
    function __unsafe_deleteDefaultRoyalty() internal {
        delete getData()._defaultRoyaltyInfo;
    }

    /**
     * @dev Sets the royalty information for a specific token id, overriding the global default.
     *
     * Requirements:
     *
     * - `receiver` cannot be the zero address.
     * - `feeNumerator` cannot be greater than the fee denominator.
     * - `msg.sender` has role ERC2981Role
     */
    function _setTokenRoyalty(uint256 tokenId, address receiver, uint96 feeNumerator) internal {
        AccessControlRecursiveLib._checkRoleRecursive(ERC2981_ROLE, msg.sender);
        __unsafe_setTokenRoyalty(tokenId, receiver, feeNumerator);
    }

    /**
     * @dev Sets the royalty information for a specific token id, overriding the global default.
     *
     * Requirements:
     *
     * - `receiver` cannot be the zero address.
     * - `feeNumerator` cannot be greater than the fee denominator.
     */
    function __unsafe_setTokenRoyalty(uint256 tokenId, address receiver, uint96 feeNumerator) internal {
        uint256 denominator = _feeDenominator();
        if (feeNumerator > denominator) {
            // Royalty fee will exceed the sale price
            revert ERC2981InvalidTokenRoyalty(tokenId, feeNumerator, denominator);
        }
        if (receiver == address(0)) {
            revert ERC2981InvalidTokenRoyaltyReceiver(tokenId, address(0));
        }

        getData()._tokenRoyaltyInfo[tokenId] = RoyaltyInfo(receiver, feeNumerator);
    }

    /**
     * @dev Resets royalty information for the token id back to the global default.
     *
     * Requirements:
     *
     * - `msg.sender` has role ERC2981Role
     */
    function _resetTokenRoyalty(uint256 tokenId) internal {
        AccessControlRecursiveLib._checkRoleRecursive(ERC2981_ROLE, msg.sender);
        __unsafe_resetTokenRoyalty(tokenId);
    }

    function __unsafe_resetTokenRoyalty(uint256 tokenId) internal {
        delete getData()._tokenRoyaltyInfo[tokenId];
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

/**
 * @dev Interface for the NFT Royalty Standard.
 *
 * A standardized way to retrieve royalty payment information for non-fungible tokens (NFTs) to enable universal
 * support for royalty payments across all NFT marketplaces and ecosystem participants.
 *
 * _Available since v4.5._
 */
interface IERC2981 {
    /**
     * @dev Returns how much royalty is owed and to whom, based on a sale price that may be denominated in any unit of
     * exchange. The royalty amount is denominated and should be paid in that same unit of exchange.
     */
    function royaltyInfo(
        uint256 tokenId,
        uint256 salePrice
    ) external view returns (address receiver, uint256 royaltyAmount);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IERC2981} from "./IERC2981.sol";

/**
 * @dev Extend IERC2981 with write functions.
 *
 */
interface IERC2981Facet is IERC2981 {
    /**
     * @dev Sets the royalty information that all ids in this contract will default to.
     *
     * Requirements:
     *
     * - `receiver` cannot be the zero address.
     * - `feeNumerator` cannot be greater than the fee denominator.
     */
    function setDefaultRoyalty(address receiver, uint96 feeNumerator) external;

    /**
     * @dev Removes default royalty information.
     */
    function deleteDefaultRoyalty() external;

    /**
     * @dev Sets the royalty information for a specific token id, overriding the global default.
     *
     * Requirements:
     *
     * - `receiver` cannot be the zero address.
     * - `feeNumerator` cannot be greater than the fee denominator.
     */
    function setTokenRoyalty(uint256 tokenId, address receiver, uint96 feeNumerator) external;

    /**
     * @dev Resets royalty information for the token id back to the global default.
     */
    function resetTokenRoyalty(uint256 tokenId) external;
}

// SPDX-License-Identifier: MIT
// Originally from
// OpenZeppelin Contracts (last updated v5.0.0) (access/AccessControl.sol)

pragma solidity ^0.8.20;

import {IAccessControl} from "./IAccessControl.sol";
import {AccessControlLib} from "./AccessControlLib.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `external constant` hash digests:
 *
 * ```solidity
 * bytes32 external constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() external {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
contract AccessControlFacet is IAccessControl {
    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with an {AccessControlUnauthorizedAccount} error including the required role.
     */
    modifier onlyRole(bytes32 role) {
        AccessControlLib._checkRole(role);
        _;
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool) {
        return AccessControlLib._hasRole(role, account);
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32) {
        return AccessControlLib._getRoleAdmin(role);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.

     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function setRoleAdmin(bytes32 role, bytes32 adminRole) external {
        AccessControlLib._setRoleAdmin(role, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) external returns (bool) {
        return AccessControlLib._grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) external returns (bool) {
        return AccessControlLib._revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address callerConfirmation) external {
        AccessControlLib._renounceRole(role, callerConfirmation);
    }
}

// SPDX-License-Identifier: MIT
// Originally from
// OpenZeppelin Contracts (last updated v5.0.0) (access/AccessControl.sol)

/**
 * We updated the AccessControl to be a library that can then be used in AccessControlFacet
 */

pragma solidity ^0.8.20;
import {IAccessControl} from "./IAccessControl.sol";

/**
 * @dev Library module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
library AccessControlLib {
    /**
     * @dev The `account` is missing a role.
     */
    error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);

    /**
     * @dev The caller of a function is not the expected one.
     *
     * NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
     */
    error AccessControlBadConfirmation();

    /**
     * @dev Cannot assign `NULL_ROLE`
     */
    error AccessControlCannotSetNullRole();

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call. This account bears the admin role (for the granted role).
     * Expected in cases where the role was granted using the internal {AccessControl-_grantRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    bytes32 constant DEFAULT_ADMIN_ROLE = 0x00;
    /**
     * The original OpenZeppelin AccessControl contract defines roles that each have an
     * `adminRole`. This is useful as a common pattern is to have the `grantRole` function
     * gated to addresses that have the `adminRole` of the role that is being currently granted.
     *
     * By default, roles have `adminRole` of `0x00` (since the storage is just empty). This is
     * also the `DEFAULT_ADMIN_ROLE`. In general, this is quite practical since we can assign
     * `DEFAULT_ADMIN_ROLE` to one address which can then distribute required roles. If we
     * visualize the relationship between roles and their `adminRole` as a tree structure we
     * realize that the root of this tree is ALWAYS the `adminRole`.
     *
     *          DEFAULT_ADMIN_ROLE
     *              /       \
     *            RoleA     RoleB
     *            /
     *          RoleC
     *
     * In other words, `DEFAULT_ADMIN_ROLE` is the indirect admin of ALL roles since it can
     * always assign itself the required roles. In this example, admin could
     * `grantRole(RoleA, msg.sender)`. The AccessControlRecursive module implements similar
     * recursive logic to support the same business logic in more scalable fashion.
     *
     * Having the admin be able to manage roles is usually good but we have a problem however.
     * How can we assign roles and freeze them, making sure that no one can re-assign the role
     * to other addresses? Only two solutions are possible:
     * 1. Renouce the `DEFAULT_ADMIN_ROLE`
     * 2. Add a `NULL_ROLE`, make it never assignable, and set that as the roles new `adminRole`
     *
     * Solution 1 is the simplest, but has the main drawback that by relinquishing the
     * `DEFAULT_ADMIN_ROLE` (forever), we lose the flexibility of being able to assign new roles,
     * especially roles with new identifiers.
     * We define `NULL_ROLE` as the `0xFF..F` (bytes32), in contrast with `0x00`.
     *
     */
    bytes32 constant NULL_ROLE = 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF;

    //https://eips.ethereum.org/EIPS/eip-7201
    bytes32 constant ACCESS_CONTROL_STORAGE =
        keccak256(abi.encode(uint256(keccak256("owlprotocol.storage.AccessControl")) - 1)) & ~bytes32(uint256(0xff));

    struct RoleData {
        mapping(address account => bool) hasRole;
        bytes32 adminRole;
    }

    /// @custom:storage-location erc7201:owlprotocol.storage.AccessControl
    struct AccessControlStorage {
        mapping(bytes32 role => RoleData) roles;
    }

    function getData() internal pure returns (AccessControlStorage storage ds) {
        bytes32 position = ACCESS_CONTROL_STORAGE;
        assembly {
            ds.slot := position
        }
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function _hasRole(bytes32 role, address account) internal view returns (bool) {
        return getData().roles[role].hasRole[account];
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
     * is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
     */
    function _checkRole(bytes32 role) internal view {
        _checkRole(role, msg.sender);
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
     * is missing `role`.
     */
    function _checkRole(bytes32 role, address account) internal view {
        if (!_hasRole(role, account)) {
            revert IAccessControl.AccessControlUnauthorizedAccount(account, role);
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function _getRoleAdmin(bytes32 role) internal view returns (bytes32) {
        //`NULL_ROLE`'s adminRole is always itself
        if (role == NULL_ROLE) {
            return NULL_ROLE;
        }

        return getData().roles[role].adminRole;
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function _renounceRole(bytes32 role, address callerConfirmation) internal {
        if (callerConfirmation != msg.sender) {
            revert IAccessControl.AccessControlBadConfirmation();
        }

        //use __unsafe here, no permissions check as removing self from role
        __unsafe_revokeRole(role, callerConfirmation);
    }

    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal {
        _checkRole(AccessControlLib._getRoleAdmin(role), msg.sender);
        __unsafe_setRoleAdmin(role, adminRole);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function __unsafe_setRoleAdmin(bytes32 role, bytes32 adminRole) internal {
        //Cannot set `NULL_ROLE` adminRole (it is always itself)
        if (role == NULL_ROLE) {
            revert AccessControlCannotSetNullRole();
        }

        //You MAY set `NULL_ROLE` as a role's `adminRole` however
        bytes32 previousAdminRole = _getRoleAdmin(role);
        getData().roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    function _grantRole(bytes32 role, address account) internal returns (bool) {
        _checkRole(AccessControlLib._getRoleAdmin(role), msg.sender);
        return __unsafe_grantRole(role, account);
    }

    /**
     * @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function __unsafe_grantRole(bytes32 role, address account) internal returns (bool) {
        //Cannot assign `NULL_ROLE` to ANY address
        if (role == NULL_ROLE) {
            revert AccessControlCannotSetNullRole();
        }

        if (!_hasRole(role, account)) {
            getData().roles[role].hasRole[account] = true;
            emit RoleGranted(role, account, msg.sender);
            return true;
        } else {
            return false;
        }
    }

    function _revokeRole(bytes32 role, address account) internal returns (bool) {
        _checkRole(AccessControlLib._getRoleAdmin(role), msg.sender);
        return __unsafe_revokeRole(role, account);
    }

    /**
     * @dev Attempts to revoke `role` to `account` and returns a boolean indicating if `role` was revoked.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function __unsafe_revokeRole(bytes32 role, address account) internal returns (bool) {
        if (_hasRole(role, account)) {
            getData().roles[role].hasRole[account] = false;
            emit RoleRevoked(role, account, msg.sender);
            return true;
        } else {
            return false;
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.20;

import {IAccessControlRecursive} from "./IAccessControlRecursive.sol";
import {AccessControlFacet} from "./AccessControlFacet.sol";
import {AccessControlLib} from "./AccessControlLib.sol";
import {AccessControlRecursiveLib} from "./AccessControlRecursiveLib.sol";

/**
 * @dev Contract module that allows nested role checks. If an address has a role (PARENT) that is the admin of another role (CHILD),
 * it is assumed to also have that role (CHILD) since it can at any time grant itself such role.
 */
contract AccessControlRecursiveFacet is IAccessControlRecursive, AccessControlFacet {
    /** Recursive Role Checks */
    /**
     * @dev Modifier that checks that an account has a specific role  or role's admin. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     */
    modifier onlyRoleRecursive(bytes32 role) {
        AccessControlRecursiveLib._checkRoleRecursive(role);
        _;
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`  or `role`'s admin.
     */
    function hasRoleRecursive(bytes32 role, address account) external view returns (bool) {
        return AccessControlRecursiveLib._hasRoleRecursive(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.

     * Requirements:
     *
     * - the caller must have ``role``'s admin role (or any recursive admin).
     */
    function setRoleAdminRecursive(bytes32 role, bytes32 adminRole) external {
        AccessControlRecursiveLib._setRoleAdminRecursive(role, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role (or any recursive admin).
     *
     * May emit a {RoleGranted} event.
     */
    function grantRoleRecursive(bytes32 role, address account) external returns (bool) {
        return AccessControlRecursiveLib._grantRoleRecursive(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role (or any recursive admin).
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRoleRecursive(bytes32 role, address account) external returns (bool) {
        return AccessControlRecursiveLib._revokeRoleRecursive(role, account);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.20;

import {Strings} from "@openzeppelin/contracts/utils/Strings.sol";
import {AccessControlLib} from "./AccessControlLib.sol";

/**
 * @dev Library module that allows nested role checks. If an address has a role (PARENT) that is the admin of another role (CHILD),
 * it is assumed to also have that role (CHILD) since it can at any time grant itself such role.
 */
library AccessControlRecursiveLib {
    /** Recursive Role Checks */
    /**
     * @dev Returns `true` if `account` has been granted `role`  or `role`'s admin.
     */
    function _hasRoleRecursive(bytes32 role, address account) internal view returns (bool) {
        //This terminates early and avoids gas overflow with infinite recursion
        if (role == AccessControlLib.NULL_ROLE) return false;
        if (role == AccessControlLib.DEFAULT_ADMIN_ROLE) return AccessControlLib._hasRole(role, account);

        return
            AccessControlLib._hasRole(role, account) ||
            _hasRoleRecursive(AccessControlLib._getRoleAdmin(role), account);
    }

    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`  or `role`'s admin.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRoleRecursive(bytes32 role) internal view {
        _checkRoleRecursive(role, msg.sender);
    }

    /**
     * @dev Revert with a standard message if `account` is missing `role` or `role`'s admin.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRoleRecursive(bytes32 role, address account) internal view {
        if (!_hasRoleRecursive(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControlRecursive: account ",
                        Strings.toHexString(account),
                        " is missing role (or recursive adminRole of)",
                        Strings.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }

    function _setRoleAdminRecursive(bytes32 role, bytes32 adminRole) internal {
        _checkRoleRecursive(AccessControlLib._getRoleAdmin(role), msg.sender);
        AccessControlLib.__unsafe_setRoleAdmin(role, adminRole);
    }

    function _grantRoleRecursive(bytes32 role, address account) internal returns (bool) {
        _checkRoleRecursive(AccessControlLib._getRoleAdmin(role), msg.sender);
        return AccessControlLib.__unsafe_grantRole(role, account);
    }

    function _revokeRoleRecursive(bytes32 role, address account) internal returns (bool) {
        _checkRoleRecursive(AccessControlLib._getRoleAdmin(role), msg.sender);
        return AccessControlLib.__unsafe_revokeRole(role, account);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/IAccessControl.sol)

pragma solidity ^0.8.20;

/**
 * @dev External interface of AccessControl declared to support ERC-165 detection.
 */
interface IAccessControl {
    /**
     * @dev The `account` is missing a role.
     */
    error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);

    /**
     * @dev The caller of a function is not the expected one.
     *
     * NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
     */
    error AccessControlBadConfirmation();

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call. This account bears the admin role (for the granted role).
     * Expected in cases where the role was granted using the internal {AccessControl-_grantRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.

     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function setRoleAdmin(bytes32 role, bytes32 adminRole) external;

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external returns (bool);

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external returns (bool);

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     */
    function renounceRole(bytes32 role, address callerConfirmation) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/IAccessControl.sol)

pragma solidity ^0.8.20;

/**
 * @dev External interface of AccessControlRecursive declared to support ERC-165 detection.
 */
interface IAccessControlRecursive {
    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRoleRecursive(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.

     * Requirements:
     *
     * - the caller must have ``role``'s admin role (or any recursive admin).
     */
    function setRoleAdminRecursive(bytes32 role, bytes32 adminRole) external;

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role (or any recursive admin).
     *
     * May emit a {RoleGranted} event.
     */
    function grantRoleRecursive(bytes32 role, address account) external returns (bool);

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role (or any recursive admin).
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRoleRecursive(bytes32 role, address account) external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;

import {IERC721BaseURI} from "./IERC721BaseURI.sol";
import {IERC721Metadata} from "./IERC721Metadata.sol";
import {ERC721Lib} from "./ERC721Lib.sol";
import {ERC721BaseURILib} from "./ERC721BaseURILib.sol";

contract ERC721BaseURIFacet is IERC721Metadata, IERC721BaseURI {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory) {
        return ERC721Lib._name();
    }

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory) {
        return ERC721Lib._symbol();
    }

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory) {
        return ERC721Lib._tokenURI(tokenId, ERC721BaseURILib._baseURI());
    }

    /**
     * @dev Returns collection-wide URI-accessible metadata
     */
    function baseURI() external view returns (string memory) {
        return ERC721BaseURILib._baseURI();
    }

    /**
     * @dev Set baseURI
     */
    function setBaseURI(string memory uri) external {
        return ERC721BaseURILib._setBaseURI(uri);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IERC721BaseURI} from "./IERC721BaseURI.sol";
import {ERC721Lib} from "./ERC721Lib.sol";
import {AccessControlRecursiveLib} from "../../access/AccessControlRecursiveLib.sol";

library ERC721BaseURILib {
    bytes32 internal constant ERC721_BASE_URI_ROLE = bytes32(IERC721BaseURI.setBaseURI.selector);

    bytes32 constant ERC721_BASE_URI_STORAGE =
        keccak256(abi.encode(uint256(keccak256("erc721.baseURI.storage")) - 1)) & ~bytes32(uint256(0xff));

    /// @custom:storage-location erc7201:erc721.baseURI.storage
    struct ERC721BaseURIStorage {
        string _baseURI;
    }

    function getData() internal pure returns (ERC721BaseURIStorage storage ds) {
        bytes32 position = ERC721_BASE_URI_STORAGE;
        assembly {
            ds.slot := position
        }
    }

    function _init(string memory uri) internal {
        __unsafe_setBaseURI(uri);
    }

    /**
     * @dev Returns collection-wide URI-accessible metadata
     */
    function _baseURI() internal view returns (string memory) {
        return getData()._baseURI;
    }

    /**
     * @dev Set baseURI
     */
    function _setBaseURI(string memory uri) internal {
        AccessControlRecursiveLib._checkRoleRecursive(ERC721_BASE_URI_ROLE, msg.sender);
        __unsafe_setBaseURI(uri);
    }

    /**
     * @dev Set baseURI
     */
    function __unsafe_setBaseURI(string memory uri) internal {
        getData()._baseURI = uri;
    }
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IERC721} from "./IERC721.sol";
import {ERC721Lib} from "./ERC721Lib.sol";

contract ERC721Facet is IERC721 {
    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance) {
        return ERC721Lib._balanceOf(owner);
    }

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner) {
        return ERC721Lib._requireOwned(tokenId);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external {
        return ERC721Lib._safeTransferFrom(from, to, tokenId, data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC-721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or
     *   {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external {
        return ERC721Lib._safeTransferFrom(from, to, tokenId);
    }

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC-721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external {
        return ERC721Lib._transferFrom(from, to, tokenId);
    }

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external {
        return ERC721Lib._approve(to, tokenId);
    }

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external {
        return ERC721Lib._setApprovalForAll(operator, approved);
    }

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator) {
        ERC721Lib._requireOwned(tokenId);

        return ERC721Lib._getApproved(tokenId);
    }

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool) {
        return ERC721Lib._isApprovedForAll(owner, operator);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/ERC721.sol)

pragma solidity ^0.8.20;

import {ERC721Utils} from "./utils/ERC721Utils.sol";
import {Strings} from "@openzeppelin/contracts/utils/Strings.sol";
import {IERC721Errors} from "./IERC721Errors.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC-721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 * Implemented as a library
 */
library ERC721Lib {
    using Strings for uint256;

    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    bytes32 constant ERC721_STORAGE =
        keccak256(abi.encode(uint256(keccak256("erc721.storage")) - 1)) & ~bytes32(uint256(0xff));

    /// @custom:storage-location erc7201:erc721.storage
    struct ERC721Storage {
        string _name;
        string _symbol;
        mapping(uint256 tokenId => address) _owners;
        mapping(address owner => uint256) _balances;
        mapping(uint256 tokenId => address) _tokenApprovals;
        mapping(address owner => mapping(address operator => bool)) _operatorApprovals;
    }

    function getData() internal pure returns (ERC721Storage storage ds) {
        bytes32 position = ERC721_STORAGE;
        assembly {
            ds.slot := position
        }
    }

    function _init(string memory name, string memory symbol) internal {
        __unsafe_setName(name);
        __unsafe_setSymbol(symbol);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function _balanceOf(address owner) internal view returns (uint256) {
        if (owner == address(0)) {
            revert IERC721Errors.ERC721InvalidOwner(address(0));
        }
        return getData()._balances[owner];
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function _name() internal view returns (string memory) {
        return getData()._name;
    }

    function __unsafe_setName(string memory name) internal {
        getData()._name = name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function _symbol() internal view returns (string memory) {
        return getData()._symbol;
    }

    function __unsafe_setSymbol(string memory symbol) internal {
        getData()._symbol = symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function _tokenURI(uint256 tokenId, string memory baseUri) internal view returns (string memory) {
        _requireOwned(tokenId);

        return bytes(baseUri).length > 0 ? string.concat(baseUri, tokenId.toString()) : "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function _approve(address to, uint256 tokenId) internal {
        _approve(to, tokenId, msg.sender);
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function _setApprovalForAll(address operator, bool approved) internal {
        _setApprovalForAll(msg.sender, operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function _isApprovedForAll(address owner, address operator) internal view returns (bool) {
        return getData()._operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function _transferFrom(address from, address to, uint256 tokenId) internal {
        if (to == address(0)) {
            revert IERC721Errors.ERC721InvalidReceiver(address(0));
        }
        // Setting an "auth" arguments enables the `_isAuthorized` check which verifies that the token exists
        // (from != 0). Therefore, it is not needed to verify that the return value is not 0 here.
        address previousOwner = _update(to, tokenId, msg.sender);
        if (previousOwner != from) {
            revert IERC721Errors.ERC721IncorrectOwner(from, tokenId, previousOwner);
        }
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function _safeTransferFrom(address from, address to, uint256 tokenId) internal {
        _safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function _safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data) internal {
        _transferFrom(from, to, tokenId);
        ERC721Utils.checkOnERC721Received(msg.sender, from, to, tokenId, data);
    }

    /**
     * @dev Returns the owner of the `tokenId`. Does NOT revert if token doesn't exist
     *
     * IMPORTANT: Any overrides to this function that add ownership of tokens not tracked by the
     * core ERC-721 logic MUST be matched with the use of {_increaseBalance} to keep balances
     * consistent with ownership. The invariant to preserve is that for any address `a` the value returned by
     * `balanceOf(a)` must be equal to the number of tokens such that `_ownerOf(tokenId)` is `a`.
     */
    function _ownerOf(uint256 tokenId) internal view returns (address) {
        return getData()._owners[tokenId];
    }

    /**
     * @dev Returns the approved address for `tokenId`. Returns 0 if `tokenId` is not minted.
     */
    function _getApproved(uint256 tokenId) internal view returns (address) {
        return getData()._tokenApprovals[tokenId];
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `owner`'s tokens, or `tokenId` in
     * particular (ignoring whether it is owned by `owner`).
     *
     * WARNING: This function assumes that `owner` is the actual owner of `tokenId` and does not verify this
     * assumption.
     */
    function _isAuthorized(address owner, address spender, uint256 tokenId) internal view returns (bool) {
        return
            spender != address(0) &&
            (owner == spender || _isApprovedForAll(owner, spender) || _getApproved(tokenId) == spender);
    }

    /**
     * @dev Checks if `spender` can operate on `tokenId`, assuming the provided `owner` is the actual owner.
     * Reverts if `spender` does not have approval from the provided `owner` for the given token or for all its assets
     * the `spender` for the specific `tokenId`.
     *
     * WARNING: This function assumes that `owner` is the actual owner of `tokenId` and does not verify this
     * assumption.
     */
    function _checkAuthorized(address owner, address spender, uint256 tokenId) internal view {
        if (!_isAuthorized(owner, spender, tokenId)) {
            if (owner == address(0)) {
                revert IERC721Errors.ERC721NonexistentToken(tokenId);
            } else {
                revert IERC721Errors.ERC721InsufficientApproval(spender, tokenId);
            }
        }
    }

    /**
     * @dev Unsafe write access to the balances, used by extensions that "mint" tokens using an {ownerOf} override.
     *
     * NOTE: the value is limited to type(uint128).max. This protect against _balance overflow. It is unrealistic that
     * a uint256 would ever overflow from increments when these increments are bounded to uint128 values.
     *
     * WARNING: Increasing an account's balance using this function tends to be paired with an override of the
     * {_ownerOf} function to resolve the ownership of the corresponding tokens so that balances and ownership
     * remain consistent with one another.
     */
    function _increaseBalance(address account, uint128 value) internal {
        unchecked {
            getData()._balances[account] += value;
        }
    }

    /**
     * @dev Transfers `tokenId` from its current owner to `to`, or alternatively mints (or burns) if the current owner
     * (or `to`) is the zero address. Returns the owner of the `tokenId` before the update.
     *
     * The `auth` argument is optional. If the value passed is non 0, then this function will check that
     * `auth` is either the owner of the token, or approved to operate on the token (by the owner).
     *
     * Emits a {Transfer} event.
     *
     * NOTE: If overriding this function in a way that tracks balances, see also {_increaseBalance}.
     */
    function _update(address to, uint256 tokenId, address auth) internal returns (address) {
        address from = _ownerOf(tokenId);

        // Perform (optional) operator check
        if (auth != address(0)) {
            _checkAuthorized(from, auth, tokenId);
        }

        // Execute the update
        if (from != address(0)) {
            // Clear approval. No need to re-authorize or emit the Approval event
            _approve(address(0), tokenId, address(0), false);

            unchecked {
                getData()._balances[from] -= 1;
            }
        }

        if (to != address(0)) {
            unchecked {
                getData()._balances[to] += 1;
            }
        }

        getData()._owners[tokenId] = to;

        emit Transfer(from, to, tokenId);

        return from;
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal {
        if (to == address(0)) {
            revert IERC721Errors.ERC721InvalidReceiver(address(0));
        }
        address previousOwner = _update(to, tokenId, address(0));
        if (previousOwner != address(0)) {
            revert IERC721Errors.ERC721InvalidSender(address(0));
        }
    }

    /**
     * @dev Mints `tokenId`, transfers it to `to` and checks for `to` acceptance.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(address to, uint256 tokenId, bytes memory data) internal {
        _mint(to, tokenId);
        ERC721Utils.checkOnERC721Received(msg.sender, address(0), to, tokenId, data);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     * This is an internal function that does not check if the sender is authorized to operate on the token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal {
        address previousOwner = _update(address(0), tokenId, address(0));
        if (previousOwner == address(0)) {
            revert IERC721Errors.ERC721NonexistentToken(tokenId);
        }
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(address from, address to, uint256 tokenId) internal {
        if (to == address(0)) {
            revert IERC721Errors.ERC721InvalidReceiver(address(0));
        }
        address previousOwner = _update(to, tokenId, address(0));
        if (previousOwner == address(0)) {
            revert IERC721Errors.ERC721NonexistentToken(tokenId);
        } else if (previousOwner != from) {
            revert IERC721Errors.ERC721IncorrectOwner(from, tokenId, previousOwner);
        }
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking that contract recipients
     * are aware of the ERC-721 standard to prevent tokens from being forever locked.
     *
     * `data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is like {safeTransferFrom} in the sense that it invokes
     * {IERC721Receiver-onERC721Received} on the receiver, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `tokenId` token must exist and be owned by `from`.
     * - `to` cannot be the zero address.
     * - `from` cannot be the zero address.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(address from, address to, uint256 tokenId) internal {
        _safeTransfer(from, to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeTransfer-address-address-uint256-}[`_safeTransfer`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeTransfer(address from, address to, uint256 tokenId, bytes memory data) internal {
        _transfer(from, to, tokenId);
        ERC721Utils.checkOnERC721Received(msg.sender, from, to, tokenId, data);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * The `auth` argument is optional. If the value passed is non 0, then this function will check that `auth` is
     * either the owner of the token, or approved to operate on all tokens held by this owner.
     *
     * Emits an {Approval} event.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address to, uint256 tokenId, address auth) internal {
        _approve(to, tokenId, auth, true);
    }

    /**
     * @dev Variant of `_approve` with an optional flag to enable or disable the {Approval} event. The event is not
     * emitted in the context of transfers.
     */
    function _approve(address to, uint256 tokenId, address auth, bool emitEvent) internal {
        // Avoid reading the owner unless necessary
        if (emitEvent || auth != address(0)) {
            address owner = _requireOwned(tokenId);

            // We do not use _isAuthorized because single-token approvals should not be able to call approve
            if (auth != address(0) && owner != auth && !_isApprovedForAll(owner, auth)) {
                revert IERC721Errors.ERC721InvalidApprover(auth);
            }

            if (emitEvent) {
                emit Approval(owner, to, tokenId);
            }
        }

        getData()._tokenApprovals[tokenId] = to;
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Requirements:
     * - operator can't be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function _setApprovalForAll(address owner, address operator, bool approved) internal {
        if (operator == address(0)) {
            revert IERC721Errors.ERC721InvalidOperator(operator);
        }
        getData()._operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Reverts if the `tokenId` doesn't have a current owner (it hasn't been minted, or it has been burned).
     * Returns the owner.
     *
     * Overrides to ownership logic should be done to {_ownerOf}.
     */
    function _requireOwned(uint256 tokenId) internal view returns (address) {
        address owner = _ownerOf(tokenId);
        if (owner == address(0)) {
            revert IERC721Errors.ERC721NonexistentToken(tokenId);
        }
        return owner;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;

import {IERC721MintableAutoId} from "./IERC721MintableAutoId.sol";
import {ERC721MintableAutoIdLib} from "./ERC721MintableAutoIdLib.sol";

contract ERC721MintableAutoIdFacet is IERC721MintableAutoId {
    /**
     * @notice Must have `erc721.roles.mint`
     * @dev Allows `erc721.roles.mint` to mint NFTs
     * @param to address to
     */
    function mint(address to) external returns (uint256) {
        return ERC721MintableAutoIdLib._mint(to);
    }

    function mintBatch(address[] memory to) external returns (uint256[] memory) {
        return ERC721MintableAutoIdLib._mintBatch(to);
    }

    /**
     * @notice Must have `erc721.roles.mint`
     * @dev Allows caller to mint NFTs (safeMint)
     * @param to address to
     */
    function safeMint(address to) external returns (uint256) {
        return ERC721MintableAutoIdLib._safeMint(to);
    }

    function safeMintBatch(address[] memory to) external returns (uint256[] memory) {
        return ERC721MintableAutoIdLib._safeMintBatch(to);
    }

    function totalSupply() external view returns (uint256) {
        return ERC721MintableAutoIdLib._totalSupply();
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IERC721MintableAutoId} from "./IERC721MintableAutoId.sol";
import {ERC721Lib} from "./ERC721Lib.sol";
import {AccessControlRecursiveLib} from "../../access/AccessControlRecursiveLib.sol";

library ERC721MintableAutoIdLib {
    bytes32 internal constant ERC721_MINTER_ROLE = bytes32(IERC721MintableAutoId.mint.selector);

    bytes32 constant ERC721_MINTABLE_AUTOID_STORAGE =
        keccak256(abi.encode(uint256(keccak256("erc721.mintableAutoId.storage")) - 1)) & ~bytes32(uint256(0xff));

    /// @custom:storage-location erc7201:erc721.mintableAutoId.storage
    struct ERC721MintableStorage {
        uint256 _totalSupply;
    }

    function getData() internal pure returns (ERC721MintableStorage storage ds) {
        bytes32 position = ERC721_MINTABLE_AUTOID_STORAGE;
        assembly {
            ds.slot := position
        }
    }

    function _mint(address to) internal returns (uint256) {
        AccessControlRecursiveLib._checkRoleRecursive(ERC721_MINTER_ROLE, msg.sender);
        return __unsafe_mint(to);
    }

    function __unsafe_mint(address to) internal returns (uint256) {
        //Increment totalSupply and cache tokenId
        uint256 tokenId;
        unchecked {
            tokenId = getData()._totalSupply + 1;
        }
        getData()._totalSupply = tokenId;

        ERC721Lib._mint(to, tokenId);

        return tokenId;
    }

    function _mintBatch(address[] memory to) internal returns (uint256[] memory) {
        AccessControlRecursiveLib._checkRoleRecursive(ERC721_MINTER_ROLE, msg.sender);
        return __unsafe_mintBatch(to);
    }

    function __unsafe_mintBatch(address[] memory to) internal returns (uint256[] memory) {
        //Increment totalSupply and cache start tokenId
        uint256 startId;
        unchecked {
            uint256 totalSupply = getData()._totalSupply;
            getData()._totalSupply = totalSupply + to.length;
            startId = totalSupply + 1;
        }

        uint256[] memory tokenIds = new uint256[](to.length);
        for (uint256 i; i < to.length; i++) {
            uint256 tokenId;
            unchecked {
                tokenId = startId + i;
            }

            tokenIds[i] = tokenId;
            ERC721Lib._mint(to[i], tokenId);
        }

        return tokenIds;
    }

    function _safeMint(address to) internal returns (uint256) {
        AccessControlRecursiveLib._checkRoleRecursive(ERC721_MINTER_ROLE, msg.sender);
        return __unsafe_safeMint(to);
    }

    function __unsafe_safeMint(address to) internal returns (uint256) {
        //Increment totalSupply and cache tokenId
        uint256 tokenId;
        unchecked {
            tokenId = getData()._totalSupply + 1;
        }
        getData()._totalSupply = tokenId;

        ERC721Lib._safeMint(to, tokenId, "");

        return tokenId;
    }

    function _safeMintBatch(address[] memory to) internal returns (uint256[] memory) {
        AccessControlRecursiveLib._checkRoleRecursive(ERC721_MINTER_ROLE, msg.sender);
        return __unsafe_safeMintBatch(to);
    }

    function __unsafe_safeMintBatch(address[] memory to) internal returns (uint256[] memory) {
        //Increment totalSupply and cache start tokenId
        uint256 startId;
        unchecked {
            uint256 totalSupply = getData()._totalSupply;
            getData()._totalSupply = totalSupply + to.length;
            startId = totalSupply + 1;
        }

        uint256[] memory tokenIds = new uint256[](to.length);
        for (uint256 i; i < to.length; i++) {
            uint256 tokenId;
            unchecked {
                tokenId = startId + i;
            }

            tokenIds[i] = tokenId;
            ERC721Lib._safeMint(to[i], tokenId, "");
        }

        return tokenIds;
    }

    function _totalSupply() internal view returns (uint256) {
        return getData()._totalSupply;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.20;

/**
 * @dev Required interface of an ERC-721 compliant contract.
 */
interface IERC721 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC-721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or
     *   {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC-721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;

interface IERC721BaseURI {
    /**
     * @dev Returns collection-wide URI-accessible metadata
     */
    function baseURI() external view returns (string memory);

    /**
     * @dev Set baseURI
     */
    function setBaseURI(string memory uri) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/extensions/IERC721Metadata.sol)

pragma solidity ^0.8.20;

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

/**
 * Interface for nested NFT that can be minted with auto-Id.
 */
interface IERC721MintableAutoId {
    /**
     * @notice Must have `erc721.roles.mint`
     * @dev Allows `erc721.roles.mint` to mint NFTs
     * @param to address to
     */
    function mint(address to) external returns (uint256);

    function mintBatch(address[] memory to) external returns (uint256[] memory);

    /**
     * @notice Must have `erc721.roles.mint`
     * @dev Allows caller to mint NFTs (safeMint)
     * @param to address to
     */
    function safeMint(address to) external returns (uint256);

    function safeMintBatch(address[] memory to) external returns (uint256[] memory);

    function totalSupply() external view returns (uint256);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.20;

import {IERC721Receiver} from "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
import {IERC721Errors} from "../IERC721Errors.sol";

/**
 * @dev Library that provide common ERC-721 utility functions.
 *
 * See https://eips.ethereum.org/EIPS/eip-721[ERC-721].
 */
library ERC721Utils {
    /**
     * @dev Performs an acceptance check for the provided `operator` by calling {IERC721-onERC721Received}
     * on the `to` address. The `operator` is generally the address that initiated the token transfer (i.e. `msg.sender`).
     *
     * The acceptance call is not executed and treated as a no-op if the target address doesn't contain code (i.e. an EOA).
     * Otherwise, the recipient must implement {IERC721Receiver-onERC721Received} and return the acceptance magic value to accept
     * the transfer.
     */
    function checkOnERC721Received(
        address operator,
        address from,
        address to,
        uint256 tokenId,
        bytes memory data
    ) internal {
        if (to.code.length > 0) {
            try IERC721Receiver(to).onERC721Received(operator, from, tokenId, data) returns (bytes4 retval) {
                if (retval != IERC721Receiver.onERC721Received.selector) {
                    // Token rejected
                    revert IERC721Errors.ERC721InvalidReceiver(to);
                }
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    // non-IERC721Receiver implementer
                    revert IERC721Errors.ERC721InvalidReceiver(to);
                } else {
                    /// @solidity memory-safe-assembly
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        }
    }
}

{
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 1000000
  },
  "evmVersion": "paris",
  "viaIR": true,
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  }
}

[{"inputs":[{"internalType":"uint256","name":"numerator","type":"uint256"},{"internalType":"uint256","name":"denominator","type":"uint256"}],"name":"ERC2981InvalidDefaultRoyalty","type":"error"},{"inputs":[{"internalType":"address","name":"receiver","type":"address"}],"name":"ERC2981InvalidDefaultRoyaltyReceiver","type":"error"},{"inputs":[{"internalType":"string","name":"contractUri","type":"string"},{"internalType":"string","name":"name","type":"string"},{"internalType":"string","name":"symbol","type":"string"},{"internalType":"string","name":"baseUri","type":"string"},{"internalType":"address","name":"royaltyReceiver","type":"address"},{"internalType":"uint96","name":"feeNumerator","type":"uint96"}],"name":"initialize","outputs":[],"stateMutability":"nonpayable","type":"function"}]

6080806040523461001657611003908161001c8239f35b600080fdfe6080604052600436101561001257600080fd5b60003560e01c63433be1cc1461002757600080fd5b34610e9c5760c07ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc360112610e9c5760043567ffffffffffffffff8111610e9c57610076903690600401610eec565b602490813567ffffffffffffffff8111610e9c57610098903690600401610eec565b60443567ffffffffffffffff8111610e9c576100b8903690600401610eec565b60643567ffffffffffffffff8111610e9c576100d8903690600401610eec565b906084359273ffffffffffffffffffffffffffffffffffffffff84168403610e9c5760a435946bffffffffffffffffffffffff86168603610e9c577fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0060405181602082017f8f7e2d929645ca415c0682921b343d96410da360ea90cf9706c3d0606a2b2331928382526020815261016e81610ea1565b519020167f01ffc9a7000000000000000000000000000000000000000000000000000000006000526020526040600020600183825416179055816040516020810190838252602081526101c081610ea1565b519020167f672bdb9a0000000000000000000000000000000000000000000000000000000060005260205260406000206001838254161790558160405160208101908382526020815261021281610ea1565b519020167f206ee4300000000000000000000000000000000000000000000000000000000060005260205260406000206001838254161790558160405160208101908382526020815261026481610ea1565b519020167f7b2de9fe000000000000000000000000000000000000000000000000000000006000526020526040600020600183825416179055816040516020810190838252602081526102b681610ea1565b519020167f80ac58cd0000000000000000000000000000000000000000000000000000000060005260205260406000206001838254161790558160405160208101908382526020815261030881610ea1565b519020167f868e999e0000000000000000000000000000000000000000000000000000000060005260205260406000206001838254161790558160405160208101908382526020815261035a81610ea1565b519020167f5b5e139f000000000000000000000000000000000000000000000000000000006000526020526040600020600183825416179055816040516020810190838252602081526103ac81610ea1565b519020167f39fb645800000000000000000000000000000000000000000000000000000000600052602052604060002060018382541617905560405160208101918252602081526103fc81610ea1565b519020167f2a55205a00000000000000000000000000000000000000000000000000000000600052602052604060002060017fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff008254161790557fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0060405160208101907f436b3d8f2dec49d3b39910c939cd947060bd262a7ee58aef870ec5be9091c6b68252602081526104ae81610ea1565b519020169080519067ffffffffffffffff8211610e6e57825490600182811c92168015610e64575b6020831014610e365781601f849311610de6575b50602090601f8311600114610d2057600092610d15575b50507fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8260011b9260031b1c19161790555b61053b610f6d565b9080519067ffffffffffffffff8211610ce757825490600182811c92168015610cdd575b6020831014610caf5781601f849311610c5f575b50602090601f8311600114610bbf57600092610bb4575b50507fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8260011b9260031b1c19161790555b60016105c6610f6d565b019080519067ffffffffffffffff8211610b8657825490600182811c92168015610b7c575b6020831014610b4e5781601f849311610afe575b50602090601f8311600114610a5e57600092610a53575b50507fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8260011b9260031b1c19161790555b7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0060405160208101907fb675b7a910bb13c7cc1b55025f6e21a38b496ecf3f7a5fb094c1d4b6f26102798252602081526106a181610ea1565b519020169080519067ffffffffffffffff8211610a2557825490600182811c92168015610a1b575b60208310146109ed5781601f84931161099a575b50602090601f83116001146108fa576000926108ef575b50507fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8260011b9260031b1c19161790555b612710806bffffffffffffffffffffffff8416116108ab575073ffffffffffffffffffffffffffffffffffffffff81161561087b5760405192604084019084821067ffffffffffffffff83111761084e57509073ffffffffffffffffffffffffffffffffffffffff916040521682526bffffffffffffffffffffffff60208301911681527fffffffffffffffffffffffff000000000000000000000000000000000000000073ffffffffffffffffffffffffffffffffffffffff7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0060405160208101907ff2c59738a5b1fd38b0de9c2227f3660284469a43b4ad499bd27a677617b5bdd482526020815261083981610ea1565b51902016935116915160a01b16179055600080f35b7f4e487b710000000000000000000000000000000000000000000000000000000060005260416004526000fd5b826040517fb6d9900a00000000000000000000000000000000000000000000000000000000815260006004820152fd5b90506044926bffffffffffffffffffffffff604051937f6f483d09000000000000000000000000000000000000000000000000000000008552166004840152820152fd5b0151905038806106f4565b600085815260208120937fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe016905b818110610982575090846001959493921061094b575b505050811b019055610726565b01517fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff60f88460031b161c1916905538808061093e565b92936020600181928786015181550195019301610928565b909150836000526020600020601f840160051c810191602085106109e3575b90601f859493920160051c01905b8181106109d457506106dd565b600081558493506001016109c7565b90915081906109b9565b867f4e487b710000000000000000000000000000000000000000000000000000000060005260226004526000fd5b91607f16916106c9565b857f4e487b710000000000000000000000000000000000000000000000000000000060005260416004526000fd5b015190503880610616565b600085815260208120937fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe016905b818110610ae65750908460019594939210610aaf575b505050811b019055610648565b01517fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff60f88460031b161c19169055388080610aa2565b92936020600181928786015181550195019301610a8c565b909150836000526020600020601f840160051c810160208510610b47575b90849392915b601f830160051c82018110610b385750506105ff565b60008155859450600101610b22565b5080610b1c565b877f4e487b710000000000000000000000000000000000000000000000000000000060005260226004526000fd5b91607f16916105eb565b867f4e487b710000000000000000000000000000000000000000000000000000000060005260416004526000fd5b01519050388061058a565b600085815260208120937fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe016905b818110610c475750908460019594939210610c10575b505050811b0190556105bc565b01517fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff60f88460031b161c19169055388080610c03565b92936020600181928786015181550195019301610bed565b909150836000526020600020601f840160051c810160208510610ca8575b90849392915b601f830160051c82018110610c99575050610573565b60008155859450600101610c83565b5080610c7d565b887f4e487b710000000000000000000000000000000000000000000000000000000060005260226004526000fd5b91607f169161055f565b877f4e487b710000000000000000000000000000000000000000000000000000000060005260416004526000fd5b015190503880610501565b9250836000526020600020906000935b7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe084168510610dcb5760019450837fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe0811610610d94575b505050811b019055610533565b01517fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff60f88460031b161c19169055388080610d87565b81810151835560209485019460019093019290910190610d30565b909150836000526020600020601f840160051c810160208510610e2f575b90849392915b601f830160051c82018110610e205750506104ea565b60008155859450600101610e0a565b5080610e04565b897f4e487b710000000000000000000000000000000000000000000000000000000060005260226004526000fd5b91607f16916104d6565b887f4e487b710000000000000000000000000000000000000000000000000000000060005260416004526000fd5b600080fd5b6040810190811067ffffffffffffffff821117610ebd57604052565b7f4e487b7100000000000000000000000000000000000000000000000000000000600052604160045260246000fd5b81601f82011215610e9c5780359067ffffffffffffffff92838311610ebd5760405193601f84017fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe0908116603f0116850190811185821017610ebd5760405282845260208383010111610e9c57816000926020809301838601378301015290565b7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0060405160208101907f52d8ad91b0e7cfb3886c3394ab0e3d825352290f5f129bc8e3a475db9f93178b825260208152610fc681610ea1565b519020169056fea26469706673582212202d8e198ec6108448829871611c22fad368dca960a5d29badecab474276d210db64736f6c63430008170033

0x6080604052600436101561001257600080fd5b60003560e01c63433be1cc1461002757600080fd5b34610e9c5760c07ffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffc360112610e9c5760043567ffffffffffffffff8111610e9c57610076903690600401610eec565b602490813567ffffffffffffffff8111610e9c57610098903690600401610eec565b60443567ffffffffffffffff8111610e9c576100b8903690600401610eec565b60643567ffffffffffffffff8111610e9c576100d8903690600401610eec565b906084359273ffffffffffffffffffffffffffffffffffffffff84168403610e9c5760a435946bffffffffffffffffffffffff86168603610e9c577fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0060405181602082017f8f7e2d929645ca415c0682921b343d96410da360ea90cf9706c3d0606a2b2331928382526020815261016e81610ea1565b519020167f01ffc9a7000000000000000000000000000000000000000000000000000000006000526020526040600020600183825416179055816040516020810190838252602081526101c081610ea1565b519020167f672bdb9a0000000000000000000000000000000000000000000000000000000060005260205260406000206001838254161790558160405160208101908382526020815261021281610ea1565b519020167f206ee4300000000000000000000000000000000000000000000000000000000060005260205260406000206001838254161790558160405160208101908382526020815261026481610ea1565b519020167f7b2de9fe000000000000000000000000000000000000000000000000000000006000526020526040600020600183825416179055816040516020810190838252602081526102b681610ea1565b519020167f80ac58cd0000000000000000000000000000000000000000000000000000000060005260205260406000206001838254161790558160405160208101908382526020815261030881610ea1565b519020167f868e999e0000000000000000000000000000000000000000000000000000000060005260205260406000206001838254161790558160405160208101908382526020815261035a81610ea1565b519020167f5b5e139f000000000000000000000000000000000000000000000000000000006000526020526040600020600183825416179055816040516020810190838252602081526103ac81610ea1565b519020167f39fb645800000000000000000000000000000000000000000000000000000000600052602052604060002060018382541617905560405160208101918252602081526103fc81610ea1565b519020167f2a55205a00000000000000000000000000000000000000000000000000000000600052602052604060002060017fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff008254161790557fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0060405160208101907f436b3d8f2dec49d3b39910c939cd947060bd262a7ee58aef870ec5be9091c6b68252602081526104ae81610ea1565b519020169080519067ffffffffffffffff8211610e6e57825490600182811c92168015610e64575b6020831014610e365781601f849311610de6575b50602090601f8311600114610d2057600092610d15575b50507fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8260011b9260031b1c19161790555b61053b610f6d565b9080519067ffffffffffffffff8211610ce757825490600182811c92168015610cdd575b6020831014610caf5781601f849311610c5f575b50602090601f8311600114610bbf57600092610bb4575b50507fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8260011b9260031b1c19161790555b60016105c6610f6d565b019080519067ffffffffffffffff8211610b8657825490600182811c92168015610b7c575b6020831014610b4e5781601f849311610afe575b50602090601f8311600114610a5e57600092610a53575b50507fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8260011b9260031b1c19161790555b7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0060405160208101907fb675b7a910bb13c7cc1b55025f6e21a38b496ecf3f7a5fb094c1d4b6f26102798252602081526106a181610ea1565b519020169080519067ffffffffffffffff8211610a2557825490600182811c92168015610a1b575b60208310146109ed5781601f84931161099a575b50602090601f83116001146108fa576000926108ef575b50507fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff8260011b9260031b1c19161790555b612710806bffffffffffffffffffffffff8416116108ab575073ffffffffffffffffffffffffffffffffffffffff81161561087b5760405192604084019084821067ffffffffffffffff83111761084e57509073ffffffffffffffffffffffffffffffffffffffff916040521682526bffffffffffffffffffffffff60208301911681527fffffffffffffffffffffffff000000000000000000000000000000000000000073ffffffffffffffffffffffffffffffffffffffff7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0060405160208101907ff2c59738a5b1fd38b0de9c2227f3660284469a43b4ad499bd27a677617b5bdd482526020815261083981610ea1565b51902016935116915160a01b16179055600080f35b7f4e487b710000000000000000000000000000000000000000000000000000000060005260416004526000fd5b826040517fb6d9900a00000000000000000000000000000000000000000000000000000000815260006004820152fd5b90506044926bffffffffffffffffffffffff604051937f6f483d09000000000000000000000000000000000000000000000000000000008552166004840152820152fd5b0151905038806106f4565b600085815260208120937fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe016905b818110610982575090846001959493921061094b575b505050811b019055610726565b01517fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff60f88460031b161c1916905538808061093e565b92936020600181928786015181550195019301610928565b909150836000526020600020601f840160051c810191602085106109e3575b90601f859493920160051c01905b8181106109d457506106dd565b600081558493506001016109c7565b90915081906109b9565b867f4e487b710000000000000000000000000000000000000000000000000000000060005260226004526000fd5b91607f16916106c9565b857f4e487b710000000000000000000000000000000000000000000000000000000060005260416004526000fd5b015190503880610616565b600085815260208120937fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe016905b818110610ae65750908460019594939210610aaf575b505050811b019055610648565b01517fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff60f88460031b161c19169055388080610aa2565b92936020600181928786015181550195019301610a8c565b909150836000526020600020601f840160051c810160208510610b47575b90849392915b601f830160051c82018110610b385750506105ff565b60008155859450600101610b22565b5080610b1c565b877f4e487b710000000000000000000000000000000000000000000000000000000060005260226004526000fd5b91607f16916105eb565b867f4e487b710000000000000000000000000000000000000000000000000000000060005260416004526000fd5b01519050388061058a565b600085815260208120937fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe016905b818110610c475750908460019594939210610c10575b505050811b0190556105bc565b01517fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff60f88460031b161c19169055388080610c03565b92936020600181928786015181550195019301610bed565b909150836000526020600020601f840160051c810160208510610ca8575b90849392915b601f830160051c82018110610c99575050610573565b60008155859450600101610c83565b5080610c7d565b887f4e487b710000000000000000000000000000000000000000000000000000000060005260226004526000fd5b91607f169161055f565b877f4e487b710000000000000000000000000000000000000000000000000000000060005260416004526000fd5b015190503880610501565b9250836000526020600020906000935b7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe084168510610dcb5760019450837fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe0811610610d94575b505050811b019055610533565b01517fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff60f88460031b161c19169055388080610d87565b81810151835560209485019460019093019290910190610d30565b909150836000526020600020601f840160051c810160208510610e2f575b90849392915b601f830160051c82018110610e205750506104ea565b60008155859450600101610e0a565b5080610e04565b897f4e487b710000000000000000000000000000000000000000000000000000000060005260226004526000fd5b91607f16916104d6565b887f4e487b710000000000000000000000000000000000000000000000000000000060005260416004526000fd5b600080fd5b6040810190811067ffffffffffffffff821117610ebd57604052565b7f4e487b7100000000000000000000000000000000000000000000000000000000600052604160045260246000fd5b81601f82011215610e9c5780359067ffffffffffffffff92838311610ebd5760405193601f84017fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffe0908116603f0116850190811185821017610ebd5760405282845260208383010111610e9c57816000926020809301838601378301015290565b7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff0060405160208101907f52d8ad91b0e7cfb3886c3394ab0e3d825352290f5f129bc8e3a475db9f93178b825260208152610fc681610ea1565b519020169056fea26469706673582212202d8e198ec6108448829871611c22fad368dca960a5d29badecab474276d210db64736f6c63430008170033